Speed Windows 11

[skiman]

Hi,

These are the specs of my PC, where I notice the same problem, slow screen.

Processor Intel(R) Core(TM) i7-8565U CPU @ 1.80GHz 2.00 GHz
Geïnstalleerd RAM-geheugen 16,0 GB (15,8 GB beschikbaar)
Type systeem 64-bits besturingssysteem, x64-processor
Editie Windows 11 Pro
Versie 21H2
Installatiedatum ‎16/‎12/‎2021
Build van besturingssysteem 22000.493
Ervaring Windows Feature Experience Pack 1000.22000.493.0

[k-insis]

"Notice" is not a valid method of measurement.

Do some tests on same hardware, write specs and timings into spreadsheet, compare numbers.

Some of slow downs can come for cpu mitigations that are enabled fully on W11 and cause (on older cpus like intel core 8xxx) a significant slowdown

This is old .prg (don't know where it is from) - it makes 1000 sle controls and posts time in seconds. Run it multiple times (10+) , then average time and compare to another system with same hw, but older OS.



#include "Xbp.ch"
#include "Appevent.ch"

PROCEDURE Appsys
RETURN

PROCEDURE MAIN
LOCAL nEvent, mp1, mp2, oXbp
LOCAL oDlg1, i, nStart, nStop

oDlg1 := XbpDialog():new(AppDesktop() ,, {0,0}, {1024,768} )
oDlg1:title := "1000 SLE Test"
oDlg1:taskList := .T.
oDlg1:create()
oDlg1:Hide()
CenterControl(oDlg1)

nStart := SECONDS()
FOR i := 1 TO 1000
oXbp := XbpSLE():new(oDlg1:DrawingArea, ,{i,i/4*3}, {100,30})
oXbp:create()
NEXT
nStop := SECONDS()
oDlg1:Show()
Msgbox("Zeit "+STR(nStop-nStart)+" Sec.")

oDlg1:Destroy()
RETURN

[skiman]

I've been asked by a couple of my colleagues to enquire if anyone else is seeing what appears to be dialog repainting / slowdown issues. I personally do not have Windows 11 yet.
...
He says that this issue is quite noticeable in how long it takes for our dialogs to open and the fact that you can see the objects being painted onscreen as the dialog is built. I have seen myself what he means but only ever over a remote connection.

He is currently looking into the possibility that our antivirus is slowing things down although our application was already added as an exception.

Hi Regan,

I was wondering if you found something for the speed problem?

I have been testing on different hardware, and Windows 11 is always slower according to Windows 10, even with older hardware.

Not only creating dialogs, but also when working with it. I noticed quite a few times that the action of a button isn't executed if you click 'fast' after closing a dialog or switching between them in my application.

[Auge_Ohr]

hi,

every new Windows is slow than older Windows Version

this is while Windows get new Feature which "old" App don´t support
Xbase++ is still using "old" GDI without Hardware Acceleration

so the 1000 SLE Sample, which i have made, will take more Time on Windows 11 than on 10 or 7

[k-insis]

That was adressed by KB5006746 on 2021-10-21

https://www.amd.com/en/support/kb/faq/pa-400

but "older" Hardware are not support by Windows 11
e.g. Ryzen 2xxx / 3xxx L3-Cache does not work correct ( -40% )

[skiman]

Hi,

We did some tests on different systems. The results are amazing, Windows 11 is so slow comparing to Windows 10. There is a big difference in the creation of a dialog, but also when destroying the dialog. This is where I notice that the click of a button isn't executed. The system is still destroying a dialog.

I don't know if this is because of the video performance, lack of hardware accelleration for GDI as Jimmy mentioned. Wondering why Windows 10 is so much faster. My laptop was also much faster before with Windows 10.

I implemented the testfunction in my application and started it on different systems. Seems as the oDlg:show is the same for all.

Code: Select all

function speedtest()
********************
LOCAL nEvent, mp1, mp2, oXbp
LOCAL oDlg1, i, nStartCreate, nStopCreate , nStartShow , nStopshow , nStartDestroy , nStopdestroy

oDlg1 := XbpDialog():new(AppDesktop() ,, {0,0}, {1024,768} )
oDlg1:title := "1000 SLE Test"
oDlg1:taskList := .T.
oDlg1:create()
oDlg1:Hide()
CenterControl(oDlg1)

nStartCreate := SECONDS()
FOR i := 1 TO 1000
oXbp := XbpSLE():new(oDlg1:DrawingArea, ,{i,i/4*3}, {100,30})
oXbp:create()
NEXT
nStopCreate := SECONDS()
nStartshow := seconds()
oDlg1:Show()
nStopShow := seconds()
nStartDestroy := SECONDS()
oDlg1:Destroy()
nStopDestroy := SECONDS()
Msgbox("Create: "+STR(nStopCreate-nStartCreate,9,2)+" Sec."+chr(13)+chr(10)+"Show: "+STR(nStopshow-nStartshow,9,2)+" Sec."+chr(13)+chr(10)+"Destroy: "+STR(nStopdestroy-nStartDestroy,9,2)+" Sec.")
RETURN nil

The result on Windows 11:
CPU: i7-8565U CPU @ 1.80GHz 2.00 GHz with 16 Gb Ram: Create: 9.24, Destroy: 4.68 (977)

Results on Windows 10:

CPU: i7-1165G7 @ 2.8 with 16 Gb: Create: 0.91, Destroy: 0.45 (609)
CPU: i5-10300H @ 2.5 Ghz with 16Gb: Create: 1.88, Destroy: 1.15 (722)
CPU: i7-7500 @ 2.7 with 8 Gb: Create 1.7, Destroy: 1.16 (1434)

The number at the end is the ranking in a CPU test on https://www.cpubenchmark.net/cpu_list.php.

So take care if your customers are buying hardware with Windows 11.

[Wolfgang Ciriack]

Hello Chris,
i testet it on my PC:
Win 11 Build 22593.1, Windows Feature Experience Pack 1000.22593.1.0
CPU i5-1135G7 with 2.40GHz, 16 GB RAM : Create: 3.16 - 3.25 (2.65 from within workbench) Destroy: 1.06 - 1.15

[Auge_Ohr]

hi Chris,

have enhance Code to run with Xbase++ and harbour/HMG

Code: Select all

#IFDEF __XPP__
#ELSE
#include "HMG.CH"
#ENDIF

PROCEDURE MAIN
LOCAL i, nStartCreate, nStopCreate , nStartShow , nStopshow , nStartDestroy , nStopdestroy
LOCAL cSLE

#IFDEF __XPP__
LOCAL nEvent, mp1, mp2, oXbp
LOCAL oDlg1

   oDlg1 := XbpDialog():new(AppDesktop() ,, {0,0}, {1024,768} )
   oDlg1:title := "1000 SLE Test"
   oDlg1:taskList := .T.
   oDlg1:create()
   oDlg1:Hide()
   CenterControl(oDlg1)

   nStartCreate := SECONDS()
   FOR i := 1 TO 1000
      oXbp := XbpSLE():new(oDlg1:DrawingArea, ,{i,i/4*3}, {100,30})
      oXbp:create()
   NEXT
   nStopCreate := SECONDS()
   nStartshow := seconds()
   oDlg1:Show()
   nStopShow := seconds()
   nStartDestroy := SECONDS()
   oDlg1:Destroy()
   nStopDestroy := SECONDS()
   Msgbox("Create: "+STR(nStopCreate-nStartCreate,9,2)+" Sec."+chr(13)+chr(10)+"Show: "+STR(nStopshow-nStartshow,9,2)+" Sec."+chr(13)+chr(10)+"Destroy: "+STR(nStopdestroy-nStartDestroy,9,2)+" Sec.")

RETURN

#ELSE

   nStartshow := seconds()
   DEFINE WINDOW InkMain ;
         AT 0, 0 ;
         WIDTH 1024 ;
         HEIGHT 768 ;
         NOSHOW ;
         ON INIT DoInit(nStartCreate, nStopCreate , nStartShow , nStopshow , nStartDestroy , nStopdestroy) ;
         TITLE "1000 SLE Test"

      nStartCreate := SECONDS()
      FOR i := 1 TO 1000
         cSLE := "TEXT_"+STRZERO(i,4)

         DEFINE TEXTBOX &cSLE
            ROW i
            COL i/4*3
            WIDTH 100
            HEIGHT 30
            FONTNAME "Arial"
            FONTSIZE 10
            TABSTOP .T.
            VISIBLE .T.
            VALUE ""
         END TEXTBOX
      NEXT
      nStopCreate := SECONDS()

   END WINDOW

   InkMain.Show()
   nStopShow := seconds()

   nStartDestroy := SECONDS()
   nStopDestroy := SECONDS()

   CENTER WINDOW InkMain
   ACTIVATE WINDOW InkMain

RETURN

PROCEDURE DoInit(nStartCreate, nStopCreate , nStartShow , nStopshow , nStartDestroy , nStopdestroy)
   MsgInfo("Create: "+STR(nStopCreate-nStartCreate,9,2)+" Sec."+chr(13)+chr(10)+"Show: "+STR(nStopshow-nStartshow,9,2)+" Sec."+chr(13)+chr(10)+"Destroy: "+STR(nStopdestroy-nStartDestroy,9,2)+" Sec.")
RETURN

#ENDIF

Xbase++ hide Windows 10

XbSpeed_hide.jpg (5.82 KiB) Viewed 9467 times

Xbase++ hide Windows 11

XbSpeed_hide_W11.jpg (5.77 KiB) Viewed 9467 times

harbour/HMG Windows 10
Note : "show" is for hole Time (see Code)

hbSpeed_hide.jpg (6.33 KiB) Viewed 9467 times

[Auge_Ohr]

but when use "Show" while create

Xbase++ Show Windows 10

XbSpeed_Show.jpg (5.92 KiB) Viewed 9467 times

Xbase++ Show Windows 11

XbSpeed_Show_W11.jpg (5.87 KiB) Viewed 9467 times

harbour/HMG Show Windows 11
Note : "show" is for hole Time (see Code)

hbSpeed_Show_W11.jpg (6.23 KiB) Viewed 9467 times

as you can see it does slow down Xbase++ when use Windows 11 ... but Time to "paint" (show) is horrible slow

i7-6700, 2.4GHz, NVM 970 Pro (Windows 11 with "Patch" without TPM / Secure Boot)

[skiman]

Hi JImmy,

I can't load the JPG files. What is the time with your tests?