How To Add A Row To A DCBROWSE ?

[GeneB]

I want to add a new row to a DCBROWSE by pressing the 'down arrow' when on the last row. Is there an example that shows how to do this?
Thanks.
GeneB

[rdonnay]

This will do it.

Code: Select all

#INCLUDE "dcdialog.CH"

FUNCTION Main()

LOCAL GetList[0], oBrowse, aDir := Directory()

@ 0,0 DCBROWSE oBrowse DATA aDir SIZE 10,10 FIT ;
      EVAL {|o|o:hitBottomBlock := {||AddItem(aDir,oBrowse)}}

DCBROWSECOL ELEMENT 1 HEADER 'File Name' WIDTH 10 PARENT oBrowse

DCREAD GUI FIT TITLE 'Hit Bottom Test' SETFOCUS @oBrowse

RETURN nil

* ----------

PROC appsys ; return

* ----------

STATIC FUNCTION AddItem( aDir, oBrowse )

LOCAL aItem := { '<new item>', 0, Ctod(''),'','',0,Ctod(''),0,Ctod(''),0}
LOCAL bSave := oBrowse:hitBottomBlock

AAdd( Adir, aItem )

oBrowse:hitBottomBlock := nil

oBrowse:refreshAll()
oBrowse:goBottom()
oBrowse:forceStable()

oBrowse:hitBottomBlock := bSave

RETURN nil

[GeneB]

This is exactly what I needed.
I really appreciate your and everyone else's help.
GeneB