DCBROWSE with HEADLINES 2 plus DCBROWSECOL with SORT issue

[reganc]

We have a few browses in our system where we have set the header to have 2 lines and also use a SORT codeblock on the column.

The DCBROWSE is as follows:

@ nRow,0 DCBROWSE oBrowse ;
DATA aDELIV ;
SIZE nBrowWid,nBrowLines ;
POINTER nPOINTER ;
FONT RBA_SayFont_Bold() ;
PRESENTATION BROW_PRES_NORMAL() ;
CURSORMODE XBPBRW_CURSOR_ROW ;
ITEMSELECTED {|| ... } ;
ITEMMARKED {|| ... };
SORTSCOLOR SortColour()[1] , SortColour()[2] ;
SORTUCOLOR SortColour()[3] , SortColour()[4] ;
HEADLINES 2 ;
RBSELECT ;
RBDOWN BrowseMenuBlock(@oBrowse) ;
TABSTOP;
ID "DM_BROWSE"

and the DCBROWSECOL is:

DCBROWSECOL ;
PARENT oBrowse ;
DATA {|nDelNmbr| ... } ;
HEADER "Deliv.;No";
FONT RBA_SayFont() ;
COLOR {|| ... } ;
WIDTH rba_col(nDEL_PICTURE+1) ;
ALIGN XBPALIGN_RIGHT ;
SORT {|| sort_col_del(aDELIV,D_ORDNMBR) } DEFAULT ;
ID "ORDNMBR"

The above column header is the correct height but only contains the word 'Deliv.'; the word 'No' is completely missing.

This is the same in all columns but only if there is a SORT clause.

I am using eXpress++ 2.00 build 266.

Anyone else have this issue? Or has it already been mentioned somewhere (I did look first, honest) and I missed it.

[rdonnay]

I recommend using the SORT BUTTONS.

Code: Select all

#INCLUDE "dcdialog.CH"

FUNCTION Main()

LOCAL GetList[0], aDir, oBrowse, oConfig

aDir := Directory()
ASort(aDir,,,{|a,b|a[1]<b[1]})

oConfig := DC_XbpPushButtonXPDefault()
oConfig:radius := 5
oConfig:fgColor := GRA_CLR_WHITE
oConfig:bgColor := GRA_CLR_DARKCYAN
oConfig:fgColorMouse := GRA_CLR_WHITE
oConfig:bgColorMouse := GRA_CLR_DARKPINK

@ 0,0 DCBROWSE oBrowse DATA aDir SIZE 100, 20 ;
      SORTCONFIG oConfig ;
      SORTSCOLOR nil, GRA_CLR_DARKRED ;
      SORTUCOLOR nil, GRA_CLR_PALEGRAY ;
      HEADLINES 2

DCBROWSECOL ELEMENT 1 HEADER 'File;Name' WIDTH 10 PARENT oBrowse ;
   SORT {||ASort(aDir,,,{|a,b|a[1]<b[1]})} DEFAULT TOOLTIP 'File Name'

DCBROWSECOL ELEMENT 2 HEADER 'Size' WIDTH 10 PARENT oBrowse ;
   SORT {||ASort(aDir,,,{|a,b|a[2]<b[2]})} TOOLTIP 'File Size'

DCBROWSECOL ELEMENT 3 HEADER 'Date' WIDTH 10 PARENT oBrowse ;
   SORT {||ASort(aDir,,,{|a,b|a[3]<b[3]})} TOOLTIP 'File Date'

DCBROWSECOL ELEMENT 4 HEADER 'Time' WIDTH 10 PARENT oBrowse ;
   SORT {||ASort(aDir,,,{|a,b|a[4]<b[4]})} TOOLTIP 'File Time'

DCREAD GUI FIT TITLE 'Sort Button Test'

RETURN nil

* ---------

PROC appsys ; RETURN